home *** CD-ROM | disk | FTP | other *** search
/ Apple II Magazines (DO) / Bootlegger Magazine (1983)(Bootleg).zip / Bootlegger Magazine (1983)(Bootleg).do / TEDITOR.bas < prev   
BASIC Source File  |  1996-12-24  |  3KB  |  81 lines
  1. 0  GOSUB 1380
  2. 20  DIM I$(500)
  3. 40  CALL 54915: TEXT : HOME : INVERSE : PRINT "YE OLE TEXT EDITOR": NORMAL 
  4. 60  PRINT " AND IT USUALLY WORKS"
  5. 80  VTAB 7
  6. 100 D$ =  CHR$(4)
  7. 120  HTAB 10: PRINT "1 = LOAD FILE INTO MEMORY": PRINT 
  8. 140  HTAB 10: PRINT "2 = EDIT-READ FILE IN MEMORY": PRINT 
  9. 160  HTAB 10: PRINT "3 = MAKE NEW FILE": PRINT 
  10. 180  HTAB 10: PRINT "4 = SAVE FILE TO DISK": PRINT 
  11. 200  HTAB 10: PRINT "5 = CATALOG DISK": PRINT 
  12. 220  HTAB 10: PRINT "6 = PRINT FILE": PRINT 
  13. 240  VTAB 22: INVERSE : PRINT "ENTER NUMBER";: NORMAL : INPUT "<CTRL-G> ";C$
  14. 260  IF  VAL(C$) <1  OR  VAL(C$) >6  THEN 240
  15. 280 C =  VAL(C$)
  16. 300  IF C = 6  THEN 1340
  17. 320  IF C = 5  THEN 440
  18. 340  IF C = 2  THEN 640
  19. 360  PRINT : INPUT "ENTER FILE NAME : ";F$
  20. 380  PRINT : INPUT "ENTER DISK DRIVE #";DR$: IF DR$ = ""  THEN DR$ = "1"
  21. 400 DR$ = ",D" +DR$
  22. 420  ON C GOTO 500,640,960,1160
  23. 440  HOME : INPUT "CATALOG DRIVE #";V$: IF V$ = ""  THEN V$ = "1"
  24. 460  PRINT  CHR$(4)"CATALOG,D";V$
  25. 480  PRINT : INVERSE : PRINT "PRESS <RETURN> FOR MENU";: NORMAL : INPUT " ";V$: GOTO 40
  26. 500  ONERR  GOTO 620
  27. 520  PRINT : FLASH : PRINT " W O R K I N G ": NORMAL 
  28. 540  PRINT D$"OPEN"F$;DR$: PRINT D$"READ"F$
  29. 560  FOR I = 1 TO 500
  30. 580  CALL 744:I$(I) =  MID$ (IN$,1)
  31. 600  NEXT 
  32. 620 I = I -1: PRINT D$"CLOSE": GOTO 40
  33. 640  PRINT : INPUT "(E)DIT OR (S)EE FILE? ";C$: IF  LEFT$(C$,1) < >"E"  AND  LEFT$(C$,1) < >"S"  THEN 640
  34. 660  IF  LEFT$(C$,1) = "E"  THEN 760
  35. 680  HOME : FOR X = 1 TO I
  36. 700  PRINT I$(X)
  37. 720  NEXT 
  38. 740  PRINT : INVERSE : PRINT "PRESS RETURN KEY";: NORMAL : INPUT " ";C$: GOTO 40
  39. 760  PRINT : INPUT "(C)ORRECT COPY OR (A)DD MORE COPY? ";Q1$: IF  LEFT$(Q1$,1) < >"C"  AND  LEFT$(Q1$,1) < >"A"  THEN 760
  40. 780  IF  LEFT$(Q1$,1) = "A"  THEN X = I +1: GOTO 960
  41. 800  FOR X = 1 TO I
  42. 820  INVERSE : PRINT "LINE #";X;" READS:": NORMAL : PRINT I$(X)
  43. 840  NEXT 
  44. 860  PRINT : INVERSE : PRINT "EDIT WHICH LINE";: NORMAL : INPUT " (0 TO END) #";Q$:X =  VAL(Q$): IF X <0  OR X >I  THEN 860
  45. 880  IF X = 0  THEN 40
  46. 900  PRINT : PRINT "CURRENT LINE READS:": PRINT I$(X)
  47. 920  PRINT : PRINT "ENTER NEW LINE:": CALL 744:I$(X) =  MID$ (IN$,1)
  48. 940  GOTO 860
  49. 960  IF C = 3  THEN X = 0
  50. 980  HOME : PRINT "YOU CAN ENTER UP TO ";500 -X;" LINES ---": PRINT "(40 CHAR/LINE MAXIMUM)"
  51. 1000  IF X >0  THEN 1040
  52. 1020 X = 1
  53. 1040  PRINT "TYPE THE 3 LETTERS '/EX' ON A LINE BY": PRINT "THEMSELVES WHEN DONE. MISTAKES CAN BE": PRINT "CORRECTED USING ITEM #2 FROM MENU."
  54. 1060  PRINT : FOR I = X TO 500
  55. 1080  CALL 744:I$(I) =  MID$ (IN$,1)
  56. 1100  IF I$(I) = "/EX"  THEN 1140
  57. 1120  NEXT 
  58. 1140 I = I -1: GOTO 40
  59. 1160  ONERR  GOTO 1280
  60. 1180  PRINT : FLASH : PRINT " W O R K I N G ": NORMAL 
  61. 1200  PRINT D$"OPEN"F$;DR$: PRINT D$"DELETE"F$
  62. 1220  PRINT D$"OPEN"F$: PRINT D$"WRITE"F$
  63. 1240  FOR X = 1 TO I: PRINT I$(X): NEXT 
  64. 1260  PRINT D$"CLOSE": PRINT D$"LOCK"F$: GOTO 40
  65. 1280  PRINT : PRINT "<CTRL-G><CTRL-G>FILE LOCKED. DELETE & REPLACE";: INPUT "? ";Q$
  66. 1300  IF  LEFT$(Q$,1) = "Y"  THEN  PRINT D$"UNLOCK"F$: GOTO 1180
  67. 1320  PRINT D$"CLOSE": GOTO 40
  68. 1340  PRINT "ENTER FILE NAME TO BE PRINTED"
  69. 1342  INPUT A$
  70. 1343  ONERR  GOTO 1355
  71. 1344 D$ =  CHR$(4)
  72. 1345  PRINT D$"MONIO"
  73. 1346  PRINT D$"PR#1"
  74. 1347  PRINT D$"OPEN ";A$
  75. 1348  PRINT D$"READ ";A$
  76. 1349  GET B$: PRINT B$;
  77. 1350  GOTO 1349
  78. 1355  PRINT D$"CLOSE"
  79. 1356  PRINT D$"PR#0"
  80. 1360  GOTO 40
  81. 1380  RESTORE :IN$ = "X": FOR J = 744 TO 766: READ I: POKE J,I: NEXT : DATA 162,0,32,117,253,160,2,138,145,105,200,169,0,145,105,200,169,2,145,105,76,57,213: RETURN